Compiler-Semantic.st 14 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717
  1. Smalltalk createPackage: 'Compiler-Semantic'!
  2. Object subclass: #LexicalScope
  3. instanceVariableNames: 'node instruction temps args outerScope blockIndex'
  4. package: 'Compiler-Semantic'!
  5. !LexicalScope commentStamp!
  6. I represent a lexical scope where variable names are associated with ScopeVars
  7. Instances are used for block scopes. Method scopes are instances of MethodLexicalScope.
  8. I am attached to a ScopeVar and method/block nodes.
  9. Each context (method/closure) get a fresh scope that inherits from its outer scope.!
  10. !LexicalScope methodsFor: 'accessing'!
  11. alias
  12. ^ '$ctx', self scopeLevel asString
  13. !
  14. allVariableNames
  15. ^ self args keys, self temps keys
  16. !
  17. args
  18. ^ args ifNil: [ args := Dictionary new ]
  19. !
  20. bindingFor: aStringOrNode
  21. ^ self pseudoVars at: aStringOrNode value ifAbsent: [
  22. self args at: aStringOrNode value ifAbsent: [
  23. self temps at: aStringOrNode value ifAbsent: [ nil ]]]
  24. !
  25. blockIndex
  26. ^ blockIndex ifNil: [ 0 ]
  27. !
  28. blockIndex: anInteger
  29. blockIndex := anInteger
  30. !
  31. instruction
  32. ^ instruction
  33. !
  34. instruction: anIRInstruction
  35. instruction := anIRInstruction
  36. !
  37. lookupVariable: aNode
  38. | lookup |
  39. lookup := (self bindingFor: aNode).
  40. lookup ifNil: [
  41. lookup := self outerScope ifNotNil: [
  42. (self outerScope lookupVariable: aNode) ]].
  43. ^ lookup
  44. !
  45. methodScope
  46. ^ self outerScope ifNotNil: [
  47. self outerScope methodScope ]
  48. !
  49. node
  50. "Answer the node in which I am defined"
  51. ^ node
  52. !
  53. node: aNode
  54. node := aNode
  55. !
  56. outerScope
  57. ^ outerScope
  58. !
  59. outerScope: aLexicalScope
  60. outerScope := aLexicalScope
  61. !
  62. pseudoVars
  63. ^ self methodScope pseudoVars
  64. !
  65. scopeLevel
  66. self outerScope ifNil: [ ^ 1 ].
  67. self isInlined ifTrue: [ ^ self outerScope scopeLevel ].
  68. ^ self outerScope scopeLevel + 1
  69. !
  70. temps
  71. ^ temps ifNil: [ temps := Dictionary new ]
  72. ! !
  73. !LexicalScope methodsFor: 'adding'!
  74. addArg: aString
  75. self args at: aString put: (ArgVar on: aString).
  76. (self args at: aString) scope: self
  77. !
  78. addTemp: aString
  79. self temps at: aString put: (TempVar on: aString).
  80. (self temps at: aString) scope: self
  81. ! !
  82. !LexicalScope methodsFor: 'testing'!
  83. canInlineNonLocalReturns
  84. ^ self isInlined and: [ self outerScope canInlineNonLocalReturns ]
  85. !
  86. isBlockScope
  87. ^ self isMethodScope not
  88. !
  89. isInlined
  90. ^ self instruction notNil and: [
  91. self instruction isInlined ]
  92. !
  93. isMethodScope
  94. ^ false
  95. ! !
  96. LexicalScope subclass: #MethodLexicalScope
  97. instanceVariableNames: 'iVars pseudoVars unknownVariables localReturn nonLocalReturns'
  98. package: 'Compiler-Semantic'!
  99. !MethodLexicalScope commentStamp!
  100. I represent a method scope.!
  101. !MethodLexicalScope methodsFor: 'accessing'!
  102. allVariableNames
  103. ^ super allVariableNames, self iVars keys
  104. !
  105. bindingFor: aNode
  106. ^ (super bindingFor: aNode) ifNil: [
  107. self iVars at: aNode value ifAbsent: [ nil ]]
  108. !
  109. iVars
  110. ^ iVars ifNil: [ iVars := Dictionary new ]
  111. !
  112. localReturn
  113. ^ localReturn ifNil: [ false ]
  114. !
  115. localReturn: aBoolean
  116. localReturn := aBoolean
  117. !
  118. methodScope
  119. ^ self
  120. !
  121. nonLocalReturns
  122. ^ nonLocalReturns ifNil: [ nonLocalReturns := OrderedCollection new ]
  123. !
  124. pseudoVars
  125. pseudoVars ifNil: [
  126. pseudoVars := Dictionary new.
  127. Smalltalk pseudoVariableNames do: [ :each |
  128. pseudoVars at: each put: ((PseudoVar on: each)
  129. scope: self methodScope;
  130. yourself) ]].
  131. ^ pseudoVars
  132. !
  133. unknownVariables
  134. ^ unknownVariables ifNil: [ unknownVariables := OrderedCollection new ]
  135. ! !
  136. !MethodLexicalScope methodsFor: 'adding'!
  137. addIVar: aString
  138. self iVars at: aString put: (InstanceVar on: aString).
  139. (self iVars at: aString) scope: self
  140. !
  141. addNonLocalReturn: aScope
  142. self nonLocalReturns add: aScope
  143. !
  144. removeNonLocalReturn: aScope
  145. self nonLocalReturns remove: aScope ifAbsent: []
  146. ! !
  147. !MethodLexicalScope methodsFor: 'testing'!
  148. canInlineNonLocalReturns
  149. ^ true
  150. !
  151. hasLocalReturn
  152. ^ self localReturn
  153. !
  154. hasNonLocalReturn
  155. ^ self nonLocalReturns notEmpty
  156. !
  157. isMethodScope
  158. ^ true
  159. ! !
  160. Object subclass: #ScopeVar
  161. instanceVariableNames: 'scope name'
  162. package: 'Compiler-Semantic'!
  163. !ScopeVar commentStamp!
  164. I am an entry in a LexicalScope that gets associated with variable nodes of the same name.
  165. There are 4 different subclasses of vars: temp vars, local vars, args, and unknown/global vars.!
  166. !ScopeVar methodsFor: 'accessing'!
  167. alias
  168. ^ self name asVariableName
  169. !
  170. name
  171. ^ name
  172. !
  173. name: aString
  174. name := aString
  175. !
  176. scope
  177. ^ scope
  178. !
  179. scope: aScope
  180. scope := aScope
  181. ! !
  182. !ScopeVar methodsFor: 'testing'!
  183. isArgVar
  184. ^ false
  185. !
  186. isClassRefVar
  187. ^ false
  188. !
  189. isImmutable
  190. ^ false
  191. !
  192. isInstanceVar
  193. ^ false
  194. !
  195. isPseudoVar
  196. ^ false
  197. !
  198. isSelf
  199. ^ false
  200. !
  201. isSuper
  202. ^ false
  203. !
  204. isTempVar
  205. ^ false
  206. !
  207. isUnknownVar
  208. ^ false
  209. !
  210. validateAssignment
  211. (self isArgVar or: [ self isPseudoVar ]) ifTrue: [
  212. InvalidAssignmentError new
  213. variableName: self name;
  214. signal]
  215. ! !
  216. !ScopeVar class methodsFor: 'instance creation'!
  217. on: aString
  218. ^ self new
  219. name: aString;
  220. yourself
  221. ! !
  222. ScopeVar subclass: #AliasVar
  223. instanceVariableNames: 'node'
  224. package: 'Compiler-Semantic'!
  225. !AliasVar commentStamp!
  226. I am an internally defined variable by the compiler!
  227. !AliasVar methodsFor: 'accessing'!
  228. node
  229. ^ node
  230. !
  231. node: aNode
  232. node := aNode
  233. ! !
  234. !AliasVar methodsFor: 'testing'!
  235. isImmutable
  236. ^ true
  237. ! !
  238. ScopeVar subclass: #ArgVar
  239. instanceVariableNames: ''
  240. package: 'Compiler-Semantic'!
  241. !ArgVar commentStamp!
  242. I am an argument of a method or block.!
  243. !ArgVar methodsFor: 'testing'!
  244. isArgVar
  245. ^ true
  246. !
  247. isImmutable
  248. ^ true
  249. ! !
  250. ScopeVar subclass: #ClassRefVar
  251. instanceVariableNames: ''
  252. package: 'Compiler-Semantic'!
  253. !ClassRefVar commentStamp!
  254. I am an class reference variable!
  255. !ClassRefVar methodsFor: 'accessing'!
  256. alias
  257. "Fixes issue #190.
  258. A function is created in the method definition, answering the class or nil.
  259. See JSStream >> #nextPutClassRefFunction:"
  260. ^ '$globals.', self name
  261. ! !
  262. !ClassRefVar methodsFor: 'testing'!
  263. isClassRefVar
  264. ^ true
  265. !
  266. isImmutable
  267. ^ true
  268. ! !
  269. ScopeVar subclass: #InstanceVar
  270. instanceVariableNames: ''
  271. package: 'Compiler-Semantic'!
  272. !InstanceVar commentStamp!
  273. I am an instance variable of a method or block.!
  274. !InstanceVar methodsFor: 'testing'!
  275. alias
  276. ^ '$self["@', self name, '"]'
  277. !
  278. isInstanceVar
  279. ^ true
  280. ! !
  281. ScopeVar subclass: #PseudoVar
  282. instanceVariableNames: ''
  283. package: 'Compiler-Semantic'!
  284. !PseudoVar commentStamp!
  285. I am an pseudo variable.
  286. The five Smalltalk pseudo variables are: 'self', 'super', 'nil', 'true' and 'false'!
  287. !PseudoVar methodsFor: 'accessing'!
  288. alias
  289. ^ self name
  290. ! !
  291. !PseudoVar methodsFor: 'testing'!
  292. isImmutable
  293. ^ true
  294. !
  295. isPseudoVar
  296. ^ true
  297. !
  298. isSelf
  299. ^ name = 'self'
  300. !
  301. isSuper
  302. ^ name = 'super'
  303. ! !
  304. ScopeVar subclass: #TempVar
  305. instanceVariableNames: ''
  306. package: 'Compiler-Semantic'!
  307. !TempVar commentStamp!
  308. I am an temporary variable of a method or block.!
  309. !TempVar methodsFor: 'testing'!
  310. isTempVar
  311. ^ true
  312. ! !
  313. ScopeVar subclass: #UnknownVar
  314. instanceVariableNames: ''
  315. package: 'Compiler-Semantic'!
  316. !UnknownVar commentStamp!
  317. I am an unknown variable. Amber uses unknown variables as JavaScript globals!
  318. !UnknownVar methodsFor: 'testing'!
  319. isUnknownVar
  320. ^ true
  321. ! !
  322. NodeVisitor subclass: #SemanticAnalyzer
  323. instanceVariableNames: 'currentScope blockIndex thePackage theClass classReferences messageSends'
  324. package: 'Compiler-Semantic'!
  325. !SemanticAnalyzer commentStamp!
  326. I semantically analyze the abstract syntax tree and annotate it with informations such as non local returns and variable scopes.!
  327. !SemanticAnalyzer methodsFor: 'accessing'!
  328. classReferences
  329. ^ classReferences ifNil: [ classReferences := Set new ]
  330. !
  331. messageSends
  332. ^ messageSends ifNil: [ messageSends := Dictionary new ]
  333. !
  334. theClass
  335. ^ theClass
  336. !
  337. theClass: aClass
  338. theClass := aClass
  339. !
  340. thePackage
  341. ^ thePackage
  342. !
  343. thePackage: aPackage
  344. thePackage := aPackage
  345. ! !
  346. !SemanticAnalyzer methodsFor: 'error handling'!
  347. errorShadowingVariable: aString
  348. ShadowingVariableError new
  349. variableName: aString;
  350. signal
  351. !
  352. errorUnknownVariable: aNode
  353. "Throw an error if the variable is undeclared in the global JS scope (i.e. window).
  354. We allow all variables listed by Smalltalk>>#globalJsVariables.
  355. This list includes: `window`, `document`, `process` and `global`
  356. for nodejs and browser environments.
  357. This is only to make sure compilation works on both browser-based and nodejs environments.
  358. The ideal solution would be to use a pragma instead"
  359. | identifier |
  360. identifier := aNode value.
  361. ((Smalltalk globalJsVariables includes: identifier) not
  362. and: [ self isVariableUndefined: identifier inPackage: self thePackage ])
  363. ifTrue: [
  364. UnknownVariableError new
  365. variableName: aNode value;
  366. signal ]
  367. ifFalse: [
  368. currentScope methodScope unknownVariables add: aNode value ]
  369. ! !
  370. !SemanticAnalyzer methodsFor: 'factory'!
  371. newBlockScope
  372. ^ self newScopeOfClass: LexicalScope
  373. !
  374. newMethodScope
  375. ^ self newScopeOfClass: MethodLexicalScope
  376. !
  377. newScopeOfClass: aLexicalScopeClass
  378. ^ aLexicalScopeClass new
  379. outerScope: currentScope;
  380. yourself
  381. ! !
  382. !SemanticAnalyzer methodsFor: 'private'!
  383. nextBlockIndex
  384. blockIndex ifNil: [ blockIndex := 0 ].
  385. blockIndex := blockIndex + 1.
  386. ^ blockIndex
  387. ! !
  388. !SemanticAnalyzer methodsFor: 'scope'!
  389. popScope
  390. currentScope ifNotNil: [
  391. currentScope := currentScope outerScope ]
  392. !
  393. pushScope: aScope
  394. aScope outerScope: currentScope.
  395. currentScope := aScope
  396. !
  397. validateVariableScope: aString
  398. "Validate the variable scope in by doing a recursive lookup, up to the method scope"
  399. (currentScope lookupVariable: aString) ifNotNil: [
  400. self errorShadowingVariable: aString ]
  401. ! !
  402. !SemanticAnalyzer methodsFor: 'testing'!
  403. isVariableUndefined: aString inPackage: aPackage
  404. aPackage ifNotNil: [
  405. | packageKnownVars |
  406. packageKnownVars := (aPackage imports
  407. reject: #isString)
  408. collect: #key.
  409. (packageKnownVars includes: aString) ifTrue: [ ^ false ]].
  410. ^ Compiler eval: 'typeof ', aString, ' === "undefined"'
  411. ! !
  412. !SemanticAnalyzer methodsFor: 'visiting'!
  413. visitAssignmentNode: aNode
  414. super visitAssignmentNode: aNode.
  415. aNode left beAssigned
  416. !
  417. visitBlockNode: aNode
  418. self pushScope: self newBlockScope.
  419. aNode scope: currentScope.
  420. currentScope node: aNode.
  421. currentScope blockIndex: self nextBlockIndex.
  422. aNode parameters do: [ :each |
  423. self validateVariableScope: each.
  424. currentScope addArg: each ].
  425. super visitBlockNode: aNode.
  426. self popScope
  427. !
  428. visitCascadeNode: aNode
  429. aNode receiver: aNode dagChildren first receiver.
  430. super visitCascadeNode: aNode
  431. !
  432. visitMethodNode: aNode
  433. self pushScope: self newMethodScope.
  434. aNode scope: currentScope.
  435. currentScope node: aNode.
  436. self theClass allInstanceVariableNames do: [ :each |
  437. currentScope addIVar: each ].
  438. aNode arguments do: [ :each |
  439. self validateVariableScope: each.
  440. currentScope addArg: each ].
  441. super visitMethodNode: aNode.
  442. aNode
  443. classReferences: self classReferences;
  444. sendIndexes: self messageSends.
  445. self popScope.
  446. ^ aNode
  447. !
  448. visitReturnNode: aNode
  449. aNode scope: currentScope.
  450. currentScope isMethodScope
  451. ifTrue: [ currentScope localReturn: true ]
  452. ifFalse: [ currentScope methodScope addNonLocalReturn: currentScope ].
  453. super visitReturnNode: aNode
  454. !
  455. visitSendNode: aNode
  456. | sends |
  457. sends := self messageSends at: aNode selector ifAbsentPut: [ OrderedCollection new ].
  458. sends add: aNode.
  459. aNode index: sends size.
  460. super visitSendNode: aNode
  461. !
  462. visitSequenceNode: aNode
  463. aNode temps do: [ :each |
  464. self validateVariableScope: each.
  465. currentScope addTemp: each ].
  466. super visitSequenceNode: aNode
  467. !
  468. visitVariableNode: aNode
  469. "Bind a ScopeVar to aNode by doing a lookup in the current scope.
  470. If no ScopeVar is found, bind a UnknowVar and throw an error."
  471. | binding |
  472. binding := currentScope lookupVariable: aNode.
  473. binding ifNil: [
  474. aNode value isCapitalized
  475. ifTrue: [ "Capital letter variables might be globals."
  476. binding := ClassRefVar new name: aNode value; yourself.
  477. self classReferences add: aNode value]
  478. ifFalse: [
  479. self errorUnknownVariable: aNode.
  480. binding := UnknownVar new name: aNode value; yourself ] ].
  481. aNode binding: binding.
  482. ! !
  483. !SemanticAnalyzer class methodsFor: 'instance creation'!
  484. on: aClass
  485. ^ self new
  486. theClass: aClass;
  487. yourself
  488. ! !
  489. CompilerError subclass: #SemanticError
  490. instanceVariableNames: ''
  491. package: 'Compiler-Semantic'!
  492. !SemanticError commentStamp!
  493. I represent an abstract semantic error thrown by the SemanticAnalyzer.
  494. Semantic errors can be unknown variable errors, etc.
  495. See my subclasses for concrete errors.
  496. The IDE should catch instances of Semantic error to deal with them when compiling!
  497. SemanticError subclass: #InvalidAssignmentError
  498. instanceVariableNames: 'variableName'
  499. package: 'Compiler-Semantic'!
  500. !InvalidAssignmentError commentStamp!
  501. I get signaled when a pseudo variable gets assigned.!
  502. !InvalidAssignmentError methodsFor: 'accessing'!
  503. messageText
  504. ^ ' Invalid assignment to variable: ', self variableName
  505. !
  506. variableName
  507. ^ variableName
  508. !
  509. variableName: aString
  510. variableName := aString
  511. ! !
  512. SemanticError subclass: #ShadowingVariableError
  513. instanceVariableNames: 'variableName'
  514. package: 'Compiler-Semantic'!
  515. !ShadowingVariableError commentStamp!
  516. I get signaled when a variable in a block or method scope shadows a variable of the same name in an outer scope.!
  517. !ShadowingVariableError methodsFor: 'accessing'!
  518. messageText
  519. ^ 'Variable shadowing error: ', self variableName, ' is already defined'
  520. !
  521. variableName
  522. ^ variableName
  523. !
  524. variableName: aString
  525. variableName := aString
  526. ! !
  527. SemanticError subclass: #UnknownVariableError
  528. instanceVariableNames: 'variableName'
  529. package: 'Compiler-Semantic'!
  530. !UnknownVariableError commentStamp!
  531. I get signaled when a variable is not defined.
  532. The default behavior is to allow it, as this is how Amber currently is able to seamlessly send messages to JavaScript objects.!
  533. !UnknownVariableError methodsFor: 'accessing'!
  534. messageText
  535. ^ 'Unknown Variable error: ', self variableName, ' is not defined'
  536. !
  537. variableName
  538. ^ variableName
  539. !
  540. variableName: aString
  541. variableName := aString
  542. ! !